Underworld — 6 of 15

Section 5 - The Hookah Hut

The Hookah hut is east of the Main Hall. "This room has large cushions laying about the floor. All of them colored in tie dye. The room is filled with smoke. No doubt from the large Hookah standing in the center of the room."

Understand "huka" or "hukka" or "huqqah" or "waterpipe" or "pipe" as the hookah.

Some cushions are enterable, scenery and supporters in the Hookah hut. "The cushions are large and made of a tough knitted fabric styled like a tie died T-Shirt. They look very comfortable to sit in."

Understand "cushion" as the cushions.

The glowing stone is a thing. The description is "A rock that glows brightly." It is lit.

Understand "rock" as the glowing stone.

A thing called the Hookah is in the Hookah hut. The Hookah is fixed in place. The description of the Hookah is "A large bottle shaped device stands in the middle of the room. It has several tubes coming out of it, water inside and smoke emanating from the top."

Instead of smelling the Hookah: say "You smell a delightful scent of rose and honey just before you begin sneezing."

Understand "pipe" or "tube" or "tubes" or "smoke" as the Hookah.

Understand "smoke [something]" as tasting.

Instead of taking, eating, tasting, or drinking the Hookah:

increment the smoke-count of the player;

say "You place a pipe from the side of [the Hookah] and put it in your mouth. You suck a large mouth full of smoke and attempt to hold your breath.[paragraph break][if the smoke-count of the player is 1]Suddenly you start coughing violently[otherwise if the smoke-count of the player is 2]Your head begins to spin[otherwise if the smoke-count of the player is 3]You become nauseous[otherwise if the smoke-count of the player is 4]The world is completely blurry. You don't feel well[otherwise]The world is so faded that all you can see is black. You feel detached from your body[end if].";

if the smoke-count of the player is greater than 4:

end the story saying "You have blacked out."

Every turn when the smoke-count of the player is greater than 1:

say "[one of]You see a strange fog roll in and encompasses you.[or]Suddenly, you see the walls twist and move as of they were under water.[or]You see blood dripping from the walls.[or]You see a pink elephant appear around the corner and then run off.[or]You hear crying next to you but when you turn there is no one there.[or]You see the room burst into flames! Quickly closing your eyes, when you open them the flames are gone.[or]You notice a white rabbit with a large watch hanging from it's neck hop into the room then promptly hop back out.[or]Fear flows through you after hearing a booming voice from above shout 'Error: cannot divide by zero!'[or]You look at your hand and realize it has grown five times a big as it was.[or]You jump out of the way of a few hundred little bugs crawling across the floor.[at random]".

The strange woman is a goddess in the Hookah hut. The description of the strange woman is "Hecate, Greek goddess of the three paths, guardian of the household, protector of everything newly born, and the goddess of witchcraft. Yeah, yeah, yeah. Whoopee-do! She may be all that but she is so not a looker. She looks like she is strung out and looking for a fix. [if the strange woman carries a sin]She is smiling at you[otherwise]She seems dismissive of you[end if]."

Understand "girl" as the strange woman.

Understand "Hecate" as the strange woman when the strange woman is proper-named.

To learn Hecate's name:

if the strange woman is not examined:

now the printed name of the strange woman is "Hecate";

now the strange woman is proper-named;

now the strange woman is examined.

Instead of examining the strange woman for the first time:

learn Hecate's name;

say "Once the smoke clears for a bit you can see that the woman is in fact Hecate, a Greek goddess.";

try examining the strange woman.

Instead of telling the strange woman about something, try asking the strange woman about it.

After asking the strange woman about a topic listed in the Table of Hecate's Replies:

if the location of Persephone is the Hookah Hut:

say "She ignores you.";

otherwise:

say "[The strange woman] looks at you and pauses to take another puff from [the Hookah]. She then calmly replies '[reply entry]'[paragraph break]".

After asking the strange woman about a topic:

if the location of Persephone is the Hookah Hut:

say "She ignores you.";

otherwise:

if the topic understood includes "herself/woman":

learn Hecate's name;

say "My name is Hecate and it is a pleasure to see you.";

otherwise:

say "After a long pause while she puffed on [the Hookah], she turns to you to say '[one of]I[']m sorry, I really don[']t know what your talking about[or]I can not conjecture on that now[or]I think you have been smoking a little to much of this [Hookah][or]Have some of [the Hookah] with me and we can contemplate on that[purely at random].'[paragraph break]".

Every turn when the player can see the strange woman and the location of Persephone is not the Hookah hut:

say "[The strange woman] [one of]takes a deep puff from [the Hookah][or]looks at you for a moment and contemplates[or]seems to be lost in thought[or]coughs and then clears her throat[purely at random].".

Instead of kissing a person, say "[if the player carries lust]Seems your carrying [lust] for a reason![otherwise]Didn[']t you already get ride of [lust]?[end if]".

Instead of giving a sin (called the sin) to the strange woman:

if the strange woman is carrying a sin:

say "She smiles and says, 'I am very happy with [the list of sins carried by the strange woman]. I do not need [the sin].'";

otherwise:

move the sin to the strange woman;

move the glowing stone to the player;

score the achievement with message "bartering with Hecate";

say "[The strange woman] gladly takes [the sin] and smiles. She gives you [a glowing stone]. 'Good luck on your travels' she says and returns to her deep thoughts."

Every turn when the smoke-count of the player is greater than 0 and the player can not see the Hookah:

decrement the smoke-count of the player;

say "[one of]The fog seems to be lifting[or]The spinning world slows down a bit[or]You feel like your standing on both feet again[or]You begin to feel a bit calmer[at random]."