Underworld — 3 of 15

Section 2 - Outside The Hut

The Garden is a room. "You are at the bottom of a hill that is covered in flourishing flowers. This garden surrounds you. Little ankle high flowers fill the dirt that surrounds a small warn path. The path heads up a hill. [if the door knob is lost]A glint under the flowers catches your eye.[end if]".

The brass door knob is a thing. The description is "A small plain brass door knob." The door knob can be found or lost. It is lost.

Some trees and the hill are scenery in the garden.

Some flowers are in the Garden. "The flowers are neatly arranged by color. They may be small but they have multiplied in such a manor to almost take over the boundaries of the garden. [if the door knob is lost]You notice something between the petals that seems out of place.[end if]". They are scenery.

Understand "flower" or "garden" or "petals" as flowers.

Instead of smelling the flowers: say "The sweet scent of candy corn fills your nostrils."

Instead of searching the flowers when the door knob is lost:

now the door knob is found;

move door knob to the Garden;

set pronouns from knob;

say "You found [a door knob]!".

Instead of searching the flowers: say "Further searching reveals nothing more."

Instead of eating or tasting the flowers, say "They do not look very appetizing."

Instead of taking the flowers, say "Please don't harm the plant life."

The Front Yard is north of the Garden. "This looks like the side of a hill and if you didn't know any better you would think that was the case. Instead, you see a few round windows set within the grassy hill and a round inset with a door big enough for you to enter if you were to crouch down a bit. There is a warn path winding down the hill to the garden."

Instead of going up in the Garden: try going north.

Instead of going down in the Front Yard: try going south.

The round windows are scenery in the Front Yard. "The windows are part of a round inset in the hill. You can see a slight glow coming from them but quickly realize that the chilled air has fogged them up so you can't see through them. Despite the fog you do notice some movement within."

Understand "window" or "glow" or "movement" or "inset" as the round windows.

The wooden door is north of the Front Yard and south of the Vestibule. It is a locked door and scenery. It is not lockable. The description is "An ornate wooden door is set into the round alcove of the hill. [if locked]You notice that the door knob has gone missing and there no way to open it now.[end if]".

Instead of opening the wooden door when the wooden door is locked: say "You cannot open this door with out replacing the missing door knob."

To fix the door:

say "You carefully slide [the door knob] onto [the wooden door] until you hear a small click. [The door knob] now looks like it is a part of [the wooden door].";

remove the door knob from play;

now the wooden door is unlocked;

score the achievement with message "fixing the wooden door".

Instead of putting the door knob on the wooden door, fix the door.

Instead of tying the door knob to the wooden door, fix the door.

Instead of inserting the door knob into the wooden door, fix the door.

Instead of unlocking the wooden door with the door knob: try putting the door knob on the wooden door.

Does the player mean doing something to the wooden door: it is very likely.

Does the player mean putting something on the wooden door: it is likely.